如何依數量產生清單?

[leonchou]

一般都是依資料清單統計數量，
但我想是不是能反過來，依數量產生清單?
例如：
Ａ欄　Ｂ欄　Ｃ欄
ＡＡＡ　２　ＡＡＡ
ＢＢＢ　３　ＡＡＡ
　　　　　　ＢＢＢ
　　　　　　ＢＢＢ
　　　　　　ＢＢＢ

如何依Ａ、Ｂ欄資料產生Ｃ欄的清單?
註：Ａ、Ｂ欄資料可能會增加。

是有人問VBA怎麼寫...
不過很好奇函數公式可辦到嗎? 謝謝！

[oobird]

蠻有愉樂價值。
C欄=IF(ROW()>SUM($B$1:$B$4),"",INDEX($A$1:$A$4,HLOOKUP(ROW(),{0,3,6,8;1,2,3,4},2)))
至於0,3,6,8就要計算B欄的數量了。
有點硬柪的感覺，不知誰可提供更好的方式？

[附件已被管理員刪除]

[bosco_yip]

看看這函數公式, 能否辦到要求 !

但數攄要放在第二行, 第一行為項目說明, 範例如下 :

A　　　　　 B　　　　 　　　 C
類別　　　數量　　　　　　 類形
AAA　　　　2　　　　　 　AAA
BBB　　　　3　　　　 　　AAA
DDD　　 　 4　　　 　 　　BBB
　　　　　　　　　　　　　BBB
　　　　　　　　　　　　　BBB
　　　　　　　　　　　　　DDD
　　　　　　　　　　　　　DDD
　　　　　　　　　　　　　DDD
　　　　　　　　　　　　　DDD

C2, 輸入陣列公式後下拖 :

{=IF(ROW(1:1)<=SUM($B$2:$B$10),INDEX($A$2:$A$10,MATCH(1,--(COUNTIF(C$1:C1,$A$2:$A$10)<$B$2:$B$10),0)),"")}

或者, 可以使用普通公式, 但返回數據, 次序會倒轉,

C2, 輸入普通公式後下拖 :

=IF(ROW(1:1)<=SUM($B$2:$B$10),LOOKUP(2,1/((COUNTIF(C$1:C1,$A$2:$A$10)<$B$2:$B$10)),$A$2:$A$10),"")

[bosco_yip]

還有使用輔助列方法, 範例如下 :

A　　　　　 B　　　　　 C　　　　　　 　D
類別　　　　數量　　　　輔助列　　　　　類形
AAA　　　　2　　 　　　1　　　　　　 　 AAA
BBB　　　　3　　　　 　3　　　　　 　　 AAA
DDD　　　　4　　　　　6　　　　　 　　 BBB
　　　　　　　　　　　　　　　　　　　　 BBB
　　　　　　　　　　　　　　　　　　　　 BBB
　　　　　　　　　　　　　　　　　　　　 DDD
　　　　　　　　　　　　　　　　　　　　 DDD
　　　　　　　　　　　　　　　　　　　　 DDD
　　　　　　　　　　　　　　　　　　　　 DDD

輔助列, C2 輸入公式後下拖 :

=IF(B2<>"",MAX(N(B1)+N(C1),1),"")

D2, 輸入普通公式後下拖 :

=IF(ROW(1:1)<=SUM($B$2:$B$10),INDEX($A$2:$A$10,MATCH(ROW(1:1),$C$2:$C$10)),"")

[leonchou]

太強了阿，無法想像！
這些公式如果有想通的一天，
腦細胞可能也死的差不多了...

感謝感謝~~

[楊威利]

新手用的笨方法

請看附檔

[附件已被管理員刪除]

[楊威利]

小學生好可憐都不能下載檔案
嗚~~~~~~~~

小學生的做法
請參考

A欄由1開始然後累加數量               
再E欄創連續數列               
再F欄用LOOKUP函數索LOOKUP(E6,A:A,B:B)               
A   B   C   D   E   F
累加   名稱   數量      數列   LOOKUP結果
1   AAA   2      1   AAA
3   BBB   3      2   AAA
6   CCC   3      3   BBB
9            4   BBB
            5   BBB
            6   CCC
            7   CCC
            8   CCC
            9   0
            10   0
            11   0
            12   0
            13   0
            14   0
            15   0
            16   0

[leonchou]

新手用的笨方法

請看附檔

謝謝你，熱心的人~

[gong]

別人的題目
試做一個
提供參考

[附件已被管理員刪除]