【常用函數】文字及資料函數

[leonchou]

作者：沙拉油

【Find】與【Search】

這二個函數基本上的用法都是一樣的，它們都是在一個字串當中尋找部分的字串。
它們兩個的差別在 Search 會將文字的大小寫視為相同，Find 則視為不相同；以及 Search 可以用萬用字元來尋找，Find 則不行。
如果找不到要找的文字內容，兩個函數一樣都會傳回錯誤值 #VALUE!。

語法：
FIND (find_text,within_text,start_num)
SEARCH(find_text,within_text,start_num)

引數 within_text 是要被尋找的字串，引數 find_text 則是你要去找的字串。
也就是要在 within_text 字串裡面尋找 find_text 字串。

引數 start_num 則是指定要從第幾個字開始找。
它是個可以省略的引數，省略後則視為從第1個字開始尋找。

範例：
假設 A1 儲存格裡面有文字串 Ade Salad Oil，則
=Find("a",A1) 會傳回 6
=FIND("a",A1,7) 會傳回 8
=FIND("lAd","Ade Salad Oil") 會傳回 #Value! （找不到會傳回錯誤值）。

=SEARCH("a",A1) 會傳回 1 （不分大小寫）
=SEARCH("d",A1,4) 會傳回 9
=SEARCH("d?o",A1) 會傳回 9

[leonchou]

作者：沙拉油

【Left】、【Mid】、【Right】與【Len】

這四個函數在公式中使用到的機率好像滿高的，而且它們也常常在同一個公式中出現，所以這一篇就乾脆通通講一下。

Left、Mid、Right 的作用都是在一個字串中抓取部分字串，而 Len 則是計算一個字串內共有幾個字元。

語法：
LEFT (text,num_chars)
MID(text,start_num,num_chars)
RIGHT(text,num_chars)
LEN(text)

說明與範例：
LEFT 函數是用來抓取從左邊算起的幾個字元。
假設 A1 儲存格裡面有文字串 Ade Salad Oil，則
=LEFT(A1,3) 會傳回 Ade
=LEFT(A1) 會傳回 A （引數 num_chars 是可以被省略的，省略時則預設為 1）

RIGHT 函數剛好與 LEFT 相反，它是用來抓取從右邊算起的幾個字元。
假設 A1 儲存格裡面有文字串 Ade Salad Oil，則
=RIGHT(A1,3) 會傳回 Oil
=RIGHT(A1) 會傳回 l （引數 num_chars 一樣是可以被省略的，省略後則預設為 1）

MID 函數則是要抓取從第幾個字元開始的幾個字元。
假設 A1 儲存格裡面有文字串 Ade Salad Oil，則
=MID(A1,5,5) 會傳回 Salad （從第5個字開始，傳回5個字）
=MID(A1,5,100) 會傳回 Salad Oil（從第5個字開始，傳回100個字；當你要傳回的字元超過A1的字元數時，只會傳回A1內僅有的字元。）

LEN 函數是計算某字串內共有幾個字元。
假設 A1 儲存格裡面有文字串 Ade Salad Oil，則
=LEN(A1) 會傳回 13

[leonchou]

作者：沙拉油

【Asc】與【Big5】

這兩個函數用法剛好相反，ASC會將全形的英文字與數字轉換成半形的英文字與數字，而BIG5則是將半形的英文字與數字轉換成全形的英文字與數字。

語法：
ASC(text)
BIG5(text)

範例：
假設A1有數字 123.45，則
=BIG5(A1) 會傳回 １２３．４５
假設A1有數字 １２３．４５，則
=ASC(A1) 會傳回 123.45

假設A1有文字 ADE沙拉
=BIG5(A1) 會傳回 ＡＤＥ沙拉 （ADE三個字變成全形字）
=ASC(BIG5(A1)) 一樣會傳回 ADE沙拉

[leonchou]

作者：沙拉油

【Lower】、【Upper】與【Proper】

這三個函數都是用在英文字上大小寫的轉換上的。
Lower 可以把英文字串全部轉換成小寫。
Upper 則是把英文字串全部轉換成大寫。
Proper 則是把一組英文字串的第一個字母轉成大寫，後面的全部轉成小寫。

語法：
LOWER(text)
UPPER(text)
PROPER(text)

範例：
=LOWER("ADE Salad OIL") 會傳回 ade salad oil
=UPPER("ADE Salad OIL") 會傳回 ADE SALAD OIL
=PROPER("a99DE-saLad OIL") 會傳回 A99De-Salad Oil

[leonchou]

作者：沙拉油

【SUBSTITUTE】

SUBSTITUTE 函數用在將文字串中的特定字串以指定字串來取代。

語法：
SUBSTITUTE(text,old_text,new_text,instance_num)
text 是要更改其內容的文字資料，或是含有文字資料的儲存格參照位址。
Old_text 為將被取代的文字字串。
New_text 為將取代 old_text 的新字串。
Instance_num 當文字字串中含有多組要以 new_text 取代 old_text 時，此引數指定要被取代的字串是文字串中的第幾組。
引數 Instance_num 可被省略，省略時會取代所有符合 Old_text 的字串。

範例：
假設A1含有數字 232366，則
=SUBSTITUTE(A1,23,"X") 會傳回 XX66
=SUBSTITUTE(A1,23,"X",2) 會傳回 23X66
=SUBSTITUTE("ADE 沙拉油","沙拉","葵花") 會傳回 ADE 葵花油

另外，這個函數常看到被用來計算某個字串裡面含有多少個指定的字串。
例如A1內有文字 80/99/3/777 要知道 A1裡面共有幾個符號 /
則需搭配 LEN 函數使用，公式為 =LEN(A1)-LEN(SUBSTITUTE(A1,"/",""))

[leonchou]

作者：沙拉油

【TEXT】

TEXT 函數用來將數值或日期資料以指定的數字或日期格式轉換為文字型態來顯示。

語法：
TEXT(value,format_text)

value 是數值或是含有數值資料的儲存格參照位址。
format_text 為 [儲存格格式] 對話方塊的 [數值] 索引標籤上的 [類別] 方塊中所使用之文字形式的數字格式。

範例：
1. 假設A1含有數字 1234，則
=TEXT(A1,"$ #,##0") 會傳回 $ 1,234
=TEXT(A1,"[DBNum2][$-404]G/通用格式") 會傳回 壹仟貳佰參拾肆
=TEXT(A1,"000000.00") 會傳回 001234.00

2. 假設A1含有日期 2005/3/27，則
=TEXT(A1,"e/mm/dd") 會傳回 94/03/27
=TEXT(A1,"mmm") 會傳回 Mar
=TEXT(A1,"aaaa") 會傳回 星期日


注意：
文字123是不等於數字123的，若要將文字型態的123用來與數字123作比較的話得先將兩個的資料型態都轉成數值或都轉成文字。
以上述的例子A1輸入1234，假設B1是公式 =TEXT(A1,"0") 而B1它也會顯示成 1234
這時候你在 C1 輸入公式 =A1=B1 是會顯示 False 的。代表A1與B1兩個儲存格的內容是不相等的。

[Baracuda]

請問 如果 A1=3 想要 B1=Mar 有無方法做

作者：沙拉油

【TEXT】

TEXT 函數用來將數值或日期資料以指定的數字或日期格式轉換為文字型態來顯示。

語法：
TEXT(value,format_text)

value 是數值或是含有數值資料的儲存格參照位址。
format_text 為 [儲存格格式] 對話方塊的 [數值] 索引標籤上的 [類別] 方塊中所使用之文字形式的數字格式。

範例：
1. 假設A1含有數字 1234，則
=TEXT(A1,"$ #,##0") 會傳回 $ 1,234
=TEXT(A1,"[DBNum2][$-404]G/通用格式") 會傳回 壹仟貳佰參拾肆
=TEXT(A1,"000000.00") 會傳回 001234.00

2. 假設A1含有日期 2005/3/27，則
=TEXT(A1,"e/mm/dd") 會傳回 94/03/27
=TEXT(A1,"mmm") 會傳回 Mar
=TEXT(A1,"aaaa") 會傳回 星期日


注意：
文字123是不等於數字123的，若要將文字型態的123用來與數字123作比較的話得先將兩個的資料型態都轉成數值或都轉成文字。
以上述的例子A1輸入1234，假設B1是公式 =TEXT(A1,"0") 而B1它也會顯示成 1234
這時候你在 C1 輸入公式 =A1=B1 是會顯示 False 的。代表A1與B1兩個儲存格的內容是不相等的。

[gong]

=TEXT(DATE(2006,A1,1),"mmm")

[bosco_yip]

=TEXT(TEXT("1"&A1,"#-#0"),"mmm")

[gong]

有創意